$!-----------------------------------------------------------------'f$verify(0)
$! @MAKEAPPS.COM
$! For WASD OpenSSL v1.1.n distribution.
$!
$! 23-NOV-2018  MGD  initial
$!-----------------------------------------------------------------------------
$!
$!! set verify
$ set control=y
$ on controly then goto finished
$!
$ define /user sys$error nl:
$ define /user sys$output nl:
$ unzip -version
$ if .not. $status
$ then
$    status = $status
$    deassign /user /nolog sys$error
$    deassign /user /nolog sys$output
$    write sys$output "UNZIP error " + status
$    exit status
$ endif
$!
$ location = f$environment("procedure")
$ location = f$parse(location,,,"device") +-
             f$parse(location,,,"directory") - "]" + "." +-
             f$edit(f$getsyi("arch_name"),"upcase") + "]"
$ location = f$edit(location,"upcase")
$ filename = location + "makeapps.opt"
$ if f$trnlnm("OPTIONS","LNM$PROCESS") then close options
$ if f$search(filename) .nes. "" then delete /noconfirm /nolog 'filename';*
$!
$ set verify
$ unzip -qod 'location' 'location'APPSOBJ.ZIP
$!'f$verify(0)
$!
$ open /write options 'filename'
$ write options "CASE_SENSITIVE=NO"
$ search_object_loop:
$    object = f$search("''location'*.obj")
$    if object .eqs. "" then goto end_search_object_loop
$    write options location + f$parse(object,,,"name") + ".obj"
$    goto search_object_loop
$ end_search_object_loop:
$ write options "''location'OSSL$LIBSSL32.OLB/LIBRARY"
$ write options "''location'OSSL$LIBCRYPTO32.OLB/LIBRARY"
$ close options
$!
$ write sys$output "link /executable='location''openssl.exe ''filename'/options"
$ link /executable='location'openssl.exe 'filename'/options
$ write sys$output "OPENSSL = ""''openssl'"""
$ openssl = "$''location'OPENSSL.EXE"
$ openssl "version"
$!
$ set verify
$ delete/noconfirm/nolog 'location'*.obj;*
$!'f$verify(0)
$!-----------------------------------------------------------------------------