$!-----------------------------------------------------------------------------
$! SOYMAIL_STARTUP.COM
$!
$! 13-JUL-2016  MGD  replace HT_ROOT references with WASD_ROOT
$! 05-MAY-2010  MGD  VAX/other privileges (per TGS)
$! 11-DEC-2009  MGD  add v10 @WASD_FILE_DEV
$! 03-OCT-2007  MGD  remove hung-over Purveyor support
$! 07-OCT-2006  MGD  privileges to support autogenous authentication
$!                   remove WORLD access from executable (bit lame but)
$!                   protect configuration file from world access
$! 26-MAR-2006  MGD  Purveyor support
$! 06-FEB-2006  MGD  add server-specific P1
$! 10-JAN-2006  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ say = "write sys$output"
$ set noon
$!
$ if f$trnlnm("WASD_FILE_DEV") .nes. "" then @wasd_file_dev
$!
$ procedure = f$element(0,";",f$environment("procedure"))
$ write sys$output f$fao("!#*>", 78-f$length(procedure)) + " " + procedure 
$!
$ privs = "/privilege=(noall,sysprv,detach,security)"
$ if (f$getsyi("HW_MODEL") .gt. 1023) -
     then privs = privs + "/authpriv=(noall,sysprv,detach,security)"
$!
$ if p1 .eqs. "APACHE" .or. -
     (p1 .eqs. "" .and. -
      f$search("apache$common:[cgi-bin]soymail.exe") .nes. "")
$ then
$    say "soyMAIL with Apache"
$    soymail_exe = "apache$common:[cgi-bin]soymail.exe"
$    install replace 'soymail_exe' 'privs'
$    if f$search("apache$common:[conf]soymail.conf") .nes. "" -
        then define /nolog /system soymail_config apache$common:[conf]soymail.conf
$    define /nolog /system soymail_lang apache$common:[soymail.lang]
$    define /nolog /system soymail_theme apache$common:[soymail.theme]
$    define /nolog /system soymail_help apache$common:[soymail.help]
$ endif
$!
$ if p1 .eqs. "OSU" .or. -
     (p1 .eqs. "" .and. -
      f$search("www_root:[bin]soymail.exe") .nes. "")
$ then
$    say "soyMAIL with OSU"
$    soymail_exe = "www_root:[bin]soymail.exe"
$    install replace 'soymail_exe' 'privs'
$    if f$search("www_root:[system]soymail.conf") .nes. "" -
        then define /nolog /system soymail_config www_root:[system]soymail.conf
$    define /nolog /system soymail_lang www_root:[soymail.lang]
$    define /nolog /system soymail_theme www_root:[soymail.theme]
$    define /nolog /system soymail_help www_root:[soymail.help]
$ endif
$!
$ if p1 .eqs. "WASD" .or. -
     (p1 .eqs. "" .and. -
      f$trnlnm("wasd_root") .nes. "" .and. -
      f$search("cgi-bin:[000000]soymail.exe") .nes. "")
$ then
$    say "soyMAIL with WASD"
$    soymail_exe = "cgi-bin:[000000]soymail.exe"
$    install replace 'soymail_exe' 'privs'
$    if f$search("wasd_root:[local]soymail.conf") .nes. "" -
        then define /nolog /system soymail_config wasd_root:[local]soymail.conf
$    define /nolog /system soymail_lang wasd_root:[src.soymail.lang]
$    define /nolog /system soymail_theme wasd_root:[src.soymail.theme]
$    define /nolog /system soymail_help wasd_root:[src.soymail.help]
$    httpd/do=dcl=purge
$ endif
$!
$ set file /protection=(w) 'soymail_exe'
$ set file /protection=(w) soymail_config
$ set acl /acl=(identifier=*,access:none) soymail_config
$!
$ write sys$output f$fao("!#*<", 78-f$length(procedure)) + " " + procedure 
$!-----------------------------------------------------------------------------