$!-----------------------------------------------------------------------------
$! BUILD_HYPERSPI.COM
$! Builds the HYPERSPI utility for both VAX and AXP systems (separately)
$!
$! 28-OCT-2000  MGD  use CGILIB object library
$! 01-DEC-1995  MGD  VAX migrate from VAX C to DEC C
$! 20-JUN-1995  MGD  initial development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""HYPERSPI""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDES + DEFINES + WARNINGS
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' HYPERSPI
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' PLOTSPI
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' GIFSPI
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OLB = "[SRC.MISC.OBJ_''ARCH_NAME']CGILIB.OLB"
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:HYPERSPI.EXE -
     'OBJECT_DIR'HYPERSPI, -
     'OBJECT_DIR'PLOTSPI, -
     'OBJECT_DIR'GIFSPI, -
     'CGILIB_OLB'/LIBRARY
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------