$!-----------------------------------------------------------------'f$verify(0)
$! SECHAN.COM
$!
$! WASD VMS Web Services, Copyright (C) 1996-2020 Mark G.Daniel.
$! This package (all associated programs), comes with ABSOLUTELY NO WARRANTY.
$! This is free software, and you are welcome to redistribute it under the
$! conditions of the GNU GENERAL PUBLIC LICENSE, version 3, or later version.
$! http://www.gnu.org/licenses/gpl.txt
$!
$! Make sure that the SECHAN.EXE utility is available.
$!
$! 07-NOV-2009  MGD  v10 logical naming schema
$! 01-NOV-2002  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ if f$trnlnm("INSTALL$DBUG") .nes. "" then set verify
$ ss$_abort = 44
$ say = "write sys$output"
$ delete = "delete"
$ if f$type(sechan) then delete/symbol sechan
$ if f$type(sechan) then delete/symbol/global sechan
$ arch_name = f$edit(f$getsyi("arch_name"),"upcase")
$ if arch_name .eqs. "ALPHA" then arch_name = "AXP"
$ vms_version = f$integer(f$extract(1,1,f$getsyi("version"))) * 10 +-
                f$integer(f$extract(3,1,f$getsyi("version")))
$ if vms_version .ge. 72 then set process /parse=traditional
$ on controly then exit ss$_abort
$!
$ if f$search("wasd_exe:sechan.exe") .eqs. ""
$ then
$!
$    if f$search("wasd_root:[src.utils]build_sechan.com") .eqs. ""
$    then
$       type sys$input
                 ******************************************
                 *  SECHAN UTILITY SOURCE CODE NOT FOUND  *
                 ******************************************

This procedure requires the use of the SECHAN utility.  This does not appear
to be available as WASD_EXE:SECHAN.EXE and the source code does not appear to
be in WASD_ROOT:[SRC.UTILS].  This must be installed before continuing.

$       exit ss$_abort
$    endif
$    type sys$input
                        *****************************
                        *  BUILDING SECHAN UTILITY  *
                        *****************************

This procedure requires the use of the SECHAN utility.  This does not appear to
be available as WASD_EXE:SECHAN.EXE and must be built before continuing.
$    current_default = f$environment("default")
$    set default wasd_root:[src.utils]
$    set noon
$    if f$search("wasd_root:[src.utils.obj_''arch_name']sechan.obj") .eqs. ""
$    then
$       @build_sechan
$    else
$       @build_sechan link
$    endif
$    set on
$    set default 'current_default'
$    say ""
$    read sys$command response /prompt="Press RETURN to continue: "
$    say ""
$!
$ endif
$!
$ if f$search("wasd_exe:sechan.exe") .eqs. ""
$ then
$    type sys$input
                  ****************************************
                  *  SECHAN UTILITY STILL NOT AVAILABLE  *
                  ****************************************

This procedure requires the use of the SECHAN utility.  This does not appear to
be available as WASD_EXE:SECHAN.EXE even after an attempted build.  This utility
must be installed before continuing.

$    exit ss$_abort
$ endif
$!
$ sechan == "$WASD_EXE:SECHAN"
$!
$!-----------------------------------------------------------------------------