$!-----------------------------------------------------------------------------
$! INSTALL.COM
$!
$! Usage: @INSTALL [INSTALL|UPDATE] [APACHE|OSU|WASD]
$!
$! 13-JUL-2016  MGD  replace HT_ROOT references with WASD_ROOT
$! 14-JAN-2006  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ say = "write sys$output"
$ arch_name = f$edit(f$getsyi("arch_name"),"upcase")
$ if arch_name .eqs. "ALPHA" then arch_name = "AXP"
$ if P1 .nes. "INSTALL" .and. P1 .nes. "UPDATE"
$ then
$    say "ERROR: First parameter must be either INSTALL or UPDATE"
$    exit
$ endif
$!
$    type sys$input

                            ********************
                            *  SOYMAIL v1.8.2  *
                            ********************

$ have_apache = 0
$ have_osu = 0
$ have_wasd = 0
$ if f$search("APACHE$ROOT:[000000]*.DIR") .nes. "" then have_apache = 1
$ if f$search("WWW_ROOT:[000000]BIN.DIR") .nes. "" then have_osu = 1
$ if f$search("WASD_ROOT:[000000]*.DIR") .nes. "" then have_wasd = 1
$ if P2 .eqs. "" .and. (have_apache + have_osu + have_wasd) .gt. 1
$ then
$    type sys$input
There appears to be more than one of Apache (SWS), OSU and WASD installed or in
use on this system.  Reinvoke this procedure with the name of the package you
wish to install soyMAIL against.

$    say "  @INSTALL ''P1' APACHE"
$    say "  @INSTALL ''P1' OSU"
$    say "  @INSTALL ''P1' WASD"
$    say ""
$    exit
$ else
$    if P2 .eqs. ""
$    then
$       if have_apache then P2 = "APACHE"
$       if have_osu then P2 = "OSU"
$       if have_wasd then P2 = "WASD"
$    endif
$    if P2 .nes. "APACHE" .and. P2 .nes. "OSU" .and. P2 .nes. "WASD"
$    then
$       type sys$input
Reinvoke this procedure with the name of the package you wish to install
soyMAIL against.

$    say "  @INSTALL ''P1' APACHE"
$    say "  @INSTALL ''P1' OSU"
$    say "  @INSTALL ''P1' WASD"
$    say ""
$    endif
$ endif
$!
$ if P2 .eqs. "APACHE"
$ then
$    say "''P1' soyMAIL for Apache (SWS) server environment."
$    say ""
$    say "  $ COPY [.OBJ_''arch_name']SOYMAIL.EXE APACHE$COMMON:[CGI-BIN]"
$    say "  $ COPY SOYMAIL_APACHE.COM APACHE$COMMON:[CGI-BIN]SOYMAIL.COM"
$    say "  $ COPY SOYMAIL_STARTUP.COM APACHE$COMMON:[000000]"
$    if P1 .eqs. "INSTALL" then say "  $ COPY SOYMAIL.CONF APACHE$COMMON:[CONF]"
$    say "  $ @SOYMAIL_STARTUP"
$ endif
$!
$ if P2 .eqs. "OSU"
$ then
$    say "''P1' soyMAIL for OSU server environment."
$    say ""
$    say "  $ COPY [.OBJ_''arch_name']SOYMAIL.EXE WWW_ROOT:[BIN]"
$    say "  $ COPY SOYMAIL_STARTUP.COM WWW_ROOT:[SYSTEM]"
$    if P1 .eqs. "INSTALL" then say "  $ COPY SOYMAIL.CONF WWW_ROOT:[SYSTEM]"
$    say "  $ @SOYMAIL_STARTUP"
$ endif
$!
$ if P2 .eqs. "WASD"
$ then
$    say "''P1' soyMAIL for WASD server environment."
$    say ""
$    say "  $ COPY [.OBJ_''arch_name']SOYMAIL.EXE WASD_ROOT:[''arch_name'-BIN]"
$    say "  $ COPY SOYMAIL_STARTUP.COM WASD_ROOT:[STARTUP]"
$    if P1 .eqs. "INSTALL" then say "  $ COPY SOYMAIL.CONF WASD_ROOT:[LOCAL]"
$    say "  $ @SOYMAIL_STARTUP"
$ endif
$!
$ say ""
$ response = ""
$ read sys$command response /prompt="Continue? [NO]: "
$ say ""
$ if .not. response then exit
$ copy = "copy/log"
$!
$ if P2 .eqs. "APACHE"
$ then
$    copy [.OBJ_'arch_name']SOYMAIL.EXE APACHE$COMMON:[CGI-BIN]
$    copy SOYMAIL_APACHE.COM APACHE$COMMON:[CGI-BIN]SOYMAIL.COM
$    copy SOYMAIL_STARTUP.COM APACHE$COMMON:[000000]
$    if P1 .eqs. "INSTALL" then copy SOYMAIL.CONF APACHE$COMMON:[CONF]
$ endif
$!
$ if P2 .eqs. "OSU"
$ then
$    copy [.OBJ_'arch_name']SOYMAIL.EXE WWW_ROOT:[BIN]
$    copy SOYMAIL_STARTUP.COM WWW_ROOT:[SYSTEM]
$    if P1 .eqs. "INSTALL" then copy SOYMAIL.CONF WWW_ROOT:[SYSTEM]
$ endif
$!
$ if P2 .eqs. "WASD"
$ then
$    copy [.OBJ_'arch_name']SOYMAIL.EXE WASD_ROOT:['arch_name'-BIN]
$    copy SOYMAIL_STARTUP.COM WASD_ROOT:[STARTUP]
$    if P1 .eqs. "INSTALL" then copy SOYMAIL.CONF WASD_ROOT:[LOCAL]
$ endif
$!
$ say ""
$ @SOYMAIL_STARTUP 'P2'
$ say ""
$!-----------------------------------------------------------------------------