$!-----------------------------------------------------------------------------
$! BUILD_WASDOC.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 12-MAY-2020  MGD  remove NAVIG8.* obsolete from v2.n
$! 22-FEB-2019  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ set noverify
$ on controly then exit 44
$!
$ write sys$output ""
$ write sys$output "Building ""WASDOC""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ if f$search("navig8.c") .nes. "" then delete [...]navig8.*;*
$!
$ arch_name = f$edit(f$getsyi("arch_name"),"upcase")
$ if arch_name .eqs. "ALPHA" then arch_name = "axp"
$!
$ defines = " /define=(__VMS_VER=70000000,__CRTL_VER=70000000)"
$ includes = " /include=[]"
$ warnings= " /warning=(disable=(preoptw))"
$ float = " /float=ieee /ieee=denorm"
$ if arch_name .eqs. "VAX" then float = ""
$ cc_options = "/decc /optimize /stand=relaxed_ansi /prefix=all" +-
               float + includes + defines + warnings
$!
$ if f$search(f$edit("OBJ_''arch_name'.DIR","upcase")) .EQS. "" -
     then create /dir [.obj_'arch_name']
$ object_dir = "[.obj_''arch_name']"
$!
$ @style_wasdoc
$!
$ P1 = f$edit(P1,"upcase")
$ if P1 .eqs. "" .or. P1 .eqs. "BUILD" .or. P1 .eqs. "COMPILE"
$ then
$    set noon
$    set verify
$    cc 'cc_options' /object='object_dir' cgi
$    cc 'cc_options' /object='object_dir' cgilib
$    cc 'cc_options' /object='object_dir' cli
$    cc 'cc_options' /object='object_dir' draw
$    cc 'cc_options' /object='object_dir' pass2
$    regex_defines = defines - ")" + "," + "STDC_HEADERS,REGEX_MALLOC)"
$    cc 'cc_options' 'regex_defines' /object='object_dir' regex
$    cc 'cc_options' /object='object_dir' render
$    cc 'cc_options' /object='object_dir' spawn
$    cc 'cc_options' /object='object_dir' test
$    cc 'cc_options' /object='object_dir' wasDOC
$!   'f$verify(0)
$    set on
$ endif
$!
$linkit:
$ if P1 .eqs. "" .or. P1 .eqs. "BUILD" .or. P1 .eqs. "LINK"
$ then
$    set noon
$    set verify
$    link /executable='object_dir'wasdoc.exe -
          'object_dir'cgi,cgilib,cli,draw,wasdoc,pass2,regex,render,spawn,test
$!   'f$verify(0)
$    set on
$ endif
$ purge /nolog 'object_dir'
$!
$!-----------------------------------------------------------------------------